Le montage des feux

La figure 1 montre un exemple de feu rouge clignotant de passage à niveau en France. On remarque une cible ronde de couleur gris foncé, entourée d’un cercle blanc avec en son centre, une ampoule rouge. Une visière permet de protéger l’ampoule de l’éclairage ambiant afin de renforcer sa visibilité. Lorsque le feu clignote, l’arrêt est obligatoire tout comme le rouge d’un feu tricolore.

Figure 1

Un feu de passage à niveau en France

Les feux de PN étaient initialement positionnés sur le côté droit de la route comme le montre la figure 2, mais actuellement, les normes de sécurité imposent d’avoir aussi des feux de PN sur le côté gauche de la route afin de renforcer leur visibilité, ce qui est très utile si le PN est situé dans un virage ou une chicane.

Figure 2

Positionnement des barrières et des feux de PN

Dans le dernier article, nous verrons comment ajouter deux feux de PN supplémentaires pour reproduire un PN contemporain. Cependant, la plupart des réseaux peuvent se contenter de deux feux, soit parce que l’époque reproduite le permet, soit parce que le réseau n’est pas visible de tous les côtés ; on peut alors se contenter de mettre deux feux fonctionnels côté visible et deux feux factices de l’autre côté comme le montre la figure 3.

Figure 3

Feux fonctionnels et feux factices

L’ampoule peut être reproduite avec une micro-LED rouge. La tension aux bornes de la LED étant de 1,8 V à peu près, et une sortie numérique d’Arduino à l’état HIGH étant à 5 V, on voit qu’on peut mettre deux LED en série avec une résistance de 470 Ω limitant le courant à quelques milliampères.

Afin de reproduire l’inertie thermique des filaments des ampoules, nous utiliserons la bibliothèque LightDimmer créée par un membre du groupe Locoduino. Les LED doivent être sur une sortie numérique délivrant de la PWM. Réservons l’entrée-sortie 3 au cas où nous aurions besoin d’une entrée générant une interruption, nous avons alors la possibilité d’utiliser les sorties 5, 6, 9, 10 et 11. La figure 4 montre le schéma de montage de nos deux LED sur la sortie 6.

Figure 4

Montage d’un ensemble de deux LED sur la carte Arduino Uno

La bibliothèque LightDimmer

Cette bibliothèque est décrite dans le fichier README à cette adresse : https://github.com/Locoduino/LightDimmer. L’installer est très simple : il suffit d’aller dans le menu Croquis de l’IDE, puis Inclure une bibliothèque > Gérer les bibliothèques. On arrive alors dans une fenêtre "Gestionnaire de bibliothèque" et il suffit alors de taper LightDimmer dans la case "Filtrez votre recherche" puis d’installer.

Il faut bien évidemment inclure cette bibliothèque au programme avec un ordre #include, puis il faut instancier un objet de type LightDimmer en lui donnant un nom (par exemple feuPN).

La fonction principale de LightDimmer est LightDimmer::update() appelée dans la loop du programme. La méthode begin(pin, level) permet de définir dans le setup à quelles sorties les LED sont reliées.

Les méthodes utilisées dans la loop parlent d’elles-mêmes :

• startBlink() permet de démarrer le clignotement.
• stopBlink() permet d’arrêter le clignotement.
• off() permet d’éteindre les LED de façon progressive (afin de ne pas les laisser allumées quand on arrête le clignotement).

Le programme

Le programme ci-dessous gère deux feux de PN branchés sur la sortie 6 de la carte Arduino Uno. Il complète le programme donné dans l’article précédent Passage à niveau géré par Arduino (1). Voici ce que nous avons ajouté :

• inclusion de la bibliothèque LightDimmer (ligne 11)
• déclaration de la sortie pour les LED (ligne 14)
• instanciation d’un objet appelé feuPN (ligne 17)
• dans le setup : feuPN.begin (LED, HIGH); permet d’initialiser LightDimmer (ligne 41)
• dans loop : arrêt du clignotement et extinction des feux (lignes 48-49) si etatZonePN est égal à false, ou bien commencement du clignotement (ligne 53) si etatZonePN est égal à true. Enfin, mise à jour de l’état des feux du PN par LightDimmer::update(); (ligne 55)

/* PN_TIB_blinkFeuPN.ino
   -----------------------------------------------------------------
   Fait clignoter un ensemble de deux feux de PN branches sur une
   meme sortie avec la bibliothèque LightDimmer lorsque la zone PN
   est occupee
   -----------------------------------------------------------------
   C BEZANGER - 2018 - 2020 Domaine public
   Derniere mise a jour : 28 mai 2020
*/

#include <LightDimmer.h>

const byte ILS=2; // entree commune a tous les ILS
const byte LED=6; // sortie pour deux feux de PN
unsigned int compteur = 1;  // compteur d evenements (survol ILS)

LightDimmer feuPN;

volatile static boolean etatZonePN = true; // Initialiser avec train en gare sur TIB
volatile static unsigned long old_top_debutISR;  // Date anterieure d appel ISR
unsigned long old_top = 0;  // variable pour afficher donnees utiles

void changeEtat() { // routine d'interruption (ISR)
  unsigned long top_debutISR = millis();  // date appel ISR
  if((top_debutISR - old_top_debutISR) > 2000) {
    // 2 secondes au moins entre execution ISR
    etatZonePN = !etatZonePN; // etat passe a etat oppose
    old_top_debutISR = top_debutISR;  // initialisation date anterieure d appel ISR
  }
} // fin de ISR

void setup() {
  // put your setup code here, to run once:
  Serial.begin(115200); // Communication avec le moniteur  
  pinMode (ILS, INPUT_PULLUP);
  pinMode (LED_BUILTIN, OUTPUT);
  // changeEtat est la routine d'interruption sur l'entree ILS
  // elle est declenchee par un front descendant
  attachInterrupt (digitalPinToInterrupt(ILS), changeEtat, FALLING);
  digitalWrite (LED_BUILTIN, LOW);
  feuPN.begin(LED, HIGH); // LED s allume avec etat haut
} // fin de setup

void loop() {
  // put your main code here, to run repeatedly:
  if(etatZonePN == false) {
    digitalWrite (LED_BUILTIN, LOW); // eteint LED de controle de la section
    feuPN.stopBlink();  // arrete le clignotement des feux de PN
    feuPN.off();        // eteint les feux de PN
  }
  if(etatZonePN == true) {
    digitalWrite (LED_BUILTIN, HIGH); // allume LED de controle de la section
    feuPN.startBlink(); // commence le clignotement des feux de PN
  }
  LightDimmer::update();
  if(old_top_debutISR != old_top) { // Affichage pour chaque nouveau survol ILS
    Serial.print(compteur);
    Serial.print("     ");
    Serial.print(old_top_debutISR);
    Serial.print("     ");
    Serial.println(old_top_debutISR - old_top);
    old_top = old_top_debutISR; 
    compteur = compteur + 1;   
  }
} // fin de loop