LOCODUINO

Forum de discussion
Dépôt GIT Locoduino
Flux RSS

mardi 17 octobre 2017

45 visiteurs en ce moment

Bibliothèque LcdUi (2)

. Par : Thierry

Comme toujours, après la théorie, la pratique…

L’exemple concret

Pour mieux illustrer l’usage de LcdUi et les bénéfices à en tirer, voyons comment coder une petite centrale DCC   de pilotage de réseau construite sur un Arduino. La partie DCC   ne sera pas traitée, ce n’est pas le but de cet article, juste l’interface utilisateur avec ses boutons et ses fenêtres… A la place, des messages seront envoyés sur la console pour simuler les changements opérés par la configuration ou l’activation des fonctions.
Côté matériel, on parle d’un encodeur (Vitesse+Ok sur la photo) qui va fixer la vitesse, avec une confirmation par le poussoir greffé sur l’axe de l’encodeur. Deux boutons à bascule permettent d’activer ou pas les fonctions F0 et F1, un bouton poussoir d’annulation (Echap), et un bouton poussoir d’urgence (Stop) pour tout arrêter si besoin. Il aurait du être rouge, mais je n’en avais pas en stock !

Après un écran d’introduction, la centrale permet de contrôler la vitesse, la direction et les deux premières fonctions de la loco courante dont l’adresse est modifiable via l’interface. En plus de l’adresse, on peut changer le nom de la loco ou l’incrément de changement de vitesse. Une option rétro éclairage pour l’écran Lcd est présente.

Voici ce que nous allons tenter de mettre en place :

Oui mais comment ?

Mettre tous ses œufs dans le même panier n’est jamais une bonne idée. Pourquoi je dis ça ? Parce que diviser pour mieux régner est une bonne pratique en programmation. Dans le cas qui nous occupe, la division va servir à améliorer la lisibilité et simplifier la maintenance, chaque source étant dédié à une partie bien identifiée du programme.

Le résultat du schisme, ce sont trois sources :

  • A gauche, Dcc.ino le croquis, le point d’entrée du programme. Il s’occupe de la partie Commanders, la bibliothèque qui va s’occuper des boutons et des événements associés, et de renvoyer son résultat au source suivant via setupUI() et loopUI().
  • Au centre, UI.cpp (et son pendant UI.hpp) qui s’occupe de toutes les fenêtres, des textes et des événements associés de l’interface utilisateur.
  • A droite, WindowLocoControl.cpp (et son pendant WindowLocoControl.hpp) qui décrit une classe de fenêtre spécifique à cette application DCC, et qui sera détaillée plus tard. Cette classe est uniquement utilisée par UI.cpp .

J’aurais tout pu mettre dans le même source Dcc.ino, mais clairement il aurait été trop long et difficile à comprendre…

Le croquis : Dcc.ino

  1. /*************************************************************
  2. project: <LCD User Interface>
  3. author: <Thierry PARIS/Locoduino>
  4. description: <LCDUI Dcc demo>
  5. *************************************************************/
  6.  
  7. #include "Commanders.h"
  8. #include "LcdUi.h"
  9. #include "UI.hpp"
  10.  
  11. ButtonsCommanderEncoder vitesse;
  12. ButtonsCommanderPush boutonOk;
  13. ButtonsCommanderPush boutonEchap;
  14. ButtonsCommanderSwitch boutonFonction0;
  15. ButtonsCommanderSwitch boutonFonction1;
  16. ButtonsCommanderPush boutonStop;
  17.  
  18. #define ENCODEUR 1000
  19. #define FONCTION0 1010
  20. #define FONCTION1 1011
  21.  
  22. void setup()
  23. {
  24. Serial.begin(115200);
  25.  
  26. Commanders::begin(LED_BUILTIN);
  27.  
  28. vitesse.begin(ENCODEUR, 12, 8);
  29. boutonOk.begin(EVENT_SELECT, A0);
  30. boutonEchap.begin(EVENT_CANCEL, A3);
  31.  
  32. boutonFonction0.AddEvent(FONCTION0, A1, COMMANDERS_EVENT_MOVE, COMMANDERS_MOVE_ON);
  33. boutonFonction0.begin();
  34.  
  35. boutonFonction1.AddEvent(FONCTION1, A2, COMMANDERS_EVENT_MOVE, COMMANDERS_MOVE_ON);
  36. boutonFonction1.begin();
  37.  
  38. boutonStop.begin(EVENT_STOP, A4);
  39. setupUI();
  40. }
  41.  
  42. void loop()
  43. {
  44. unsigned long evenement = Commanders::loop();
  45. byte evenementUI = EVENT_NONE;
  46.  
  47. switch (evenement)
  48. {
  49. case EVENT_MORE:
  50. case EVENT_LESS:
  51. case EVENT_SELECT:
  52. case EVENT_CANCEL:
  53. case EVENT_STOP:
  54. evenementUI = (byte)evenement;
  55. break;
  56. case ENCODEUR:
  57. if (Commanders::GetLastEventType() == COMMANDERS_EVENT_MOVE)
  58. {
  59. if (Commanders::GetLastEventData() == +1)
  60. evenementUI = EVENT_MORE;
  61. else
  62. evenementUI = EVENT_LESS;
  63. }
  64. break;
  65. case FONCTION0:
  66. if (Commanders::GetLastEventType() == COMMANDERS_EVENT_MOVE)
  67. {
  68. if (Commanders::GetLastEventData() == COMMANDERS_MOVE_ON)
  69. Serial.println("Function 0 activated");
  70. else
  71. Serial.println("Function 0 disactivated");
  72. }
  73. break;
  74. case FONCTION1:
  75. if (Commanders::GetLastEventType() == COMMANDERS_EVENT_MOVE)
  76. {
  77. if (Commanders::GetLastEventData() == COMMANDERS_MOVE_ON)
  78. Serial.println("Function 1 activated");
  79. else
  80. Serial.println("Function 1 disactivated");
  81. }
  82. break;
  83. }
  84.  
  85. loopUI(evenementUI);
  86. }

Le rôle du croquis va être de fixer les boutons, et de transmettre à UI les événements qui en découlent. Sa compacité le rendra facile à maintenir. L’utilisation de Commanders pour la gestion des divers boutons va aussi considérablement simplifier le croquis…
Le schéma est assez simple : déclaration des boutons et des constantes avant le setup. Dans le setup initialisation desdits boutons avec les bonnes broches et les événements à envoyer pour les interrupteurs de fonction, avant l’appel à la fonction setupUI(). Elle fait partie du fichier UI.cpp et initialise toute la partie LcdUi.
Guère plus de complication dans le loop(). Commanders est interrogé pour savoir si un bouton a été actionné. Le switch qui suit sert à transformer un événement Commanders en événement attendu par LcdUi limité aux déplacements dans les menus. Les événements supplémentaires, comme l’activation des fonctions, sont gérés directement ici dans le switch sans passer par LcdUi. L’activation ou non n’a en effet aucune influence sur les fenêtres de LcdUi. Enfin, la fonction loopUI() est appelée pour laisser LcdUi faire son travail d’affichage si besoin.
Les broches utilisées sont des broches analogiques parce que mon matériel, celui en photo, était déjà monté comme cela pour libérer les broches usuelles du Nano embarqué…

La partie LcdUI : UI.hpp

  1. #define EVENT_STOP 10
  2.  
  3. void setupUI();
  4. void loopUI(byte inEvenement);

Le rôle d’un fichier include est de déclarer ce que d’autres fichiers pourront vouloir utiliser, comme des constantes ou des fonctions. C’est exactement ce qui est fait dans UI.hpp, avec la déclaration d’un nouveau type d’événement local pour le bouton d’urgence. Puis la déclaration simplissime de l’interface des fonctions setupUI() et loopUI(). Cette dernière reçoit en argument l’événement trouvé grâce à Commanders.

La partie LcdUi : UI.cpp

L’entête

  1. /*************************************************************
  2. project: <LCD User Interface>
  3. author: <Thierry PARIS/Locoduino>
  4. description: <LCDUI DCC demo>
  5. *************************************************************/
  6.  
  7. #include "Commanders.h"
  8. #include "LcdUi.h"
  9.  
  10. #include "ScreenLiquid.hpp"
  11. #include "WindowLocoControl.hpp"
  12. #include "UI.hpp"

Après les commentaires d’usage, les includes. D’abord les bibliothèques utilisées, Commanders et bien sûr LcdUi. Ensuite vient ScreenLiquid, qui fait partie de LcdUi et déclare un écran Lcd utilisant la bibliothèque LiquidCrystal livrée avec l’IDE Arduino. WindowLocoControl définit un nouveau type de fenêtre personnalisée. Nous verrons en détail ce que cela implique. Enfin UI.hpp, surtout pour sa constante EVENT_STOP qui doit être connue à la fois par le croquis et par UI.cpp. La déclaration des fonctions contenue dans UI.hpp est superflue, mais ne pose pas de problème.
Comme expliqué dans le premier article, il y a trois parties à déclarer pour fabriquer une interface utilisateur. Une liste de textes qui vont constituer les choix possibles et les questions posées, la succession d’écrans qui va décrire le cheminement de l’utilisateur, et la gestion des événements des différentes fenêtres dans le loop().

La prose

Bon, avec seize ou vingt caractères selon l’écran, l’envolée lyrique risque d’être limitée… Je rappelle que la liste des textes à utiliser dans les fenêtres doit suivre trois règles : la longueur des textes doit rester inférieure à la taille de l’écran utilisé, les textes doivent être en mémoire programme, et la liste des textes doit elle aussi être en mémoire programme. Pour faire simple, il suffit de copier/coller à partir des exemples fournis et de remplacer par vos textes…

  1. // Declarations des textes
  2. const char str_stop[] PROGMEM = "Arret Urgence";
  3. const char str_stop2[] PROGMEM = "Appuyer Annuler";
  4. const char str_choixprincipal[] PROGMEM = "Menu principal:";
  5. const char str_controleloco[] PROGMEM = "Controle loco";
  6. const char str_choixconfig[] PROGMEM = "Configuration";
  7. const char str_resetconfig[] PROGMEM = "Reset Config";
  8. const char str_oui[] PROGMEM = "oui";
  9. const char str_non[] PROGMEM = "non";
  10. const char str_confirmer[] PROGMEM = "Sur ?";
  11. const char str_retroeclairage[] PROGMEM = "Retro eclairage";
  12. const char str_increment[] PROGMEM = "Vit Increment";
  13. const char str_nomloco[] PROGMEM = "Nom";
  14. const char str_adresseloco[] PROGMEM = "Adresse Loco";
  15. const char str_splash1[] PROGMEM = "LcdUI Demo";
  16. const char str_splash2[] PROGMEM = "For ... you !";
  17. const char str_supprimer[] PROGMEM = "Supprimer";

D’abord on déclare toutes les chaînes qui vont servir pendant le fonctionnement. Le PROGMEM est bien là et atteste qu’elles seront stockées dans la mémoire programme.

  1. // Liste des textes
  2. const char * const string_table[] PROGMEM =
  3. {
  4. str_stop,
  5. str_stop2,
  6. str_choixprincipal,
  7. str_controleloco,
  8. str_choixconfig,
  9. str_resetconfig,
  10. str_oui,
  11. str_non,
  12. str_confirmer,
  13. str_retroeclairage,
  14. str_increment,
  15. str_nomloco,
  16. str_adresseloco,
  17. str_splash1,
  18. str_splash2,
  19. str_supprimer
  20. };

Ensuite on fabrique une liste string_table de pointeurs sur ces chaînes pour les rassembler. Cette liste est elle même en mémoire programme grâce à PROGMEM.

  1. // Indices dans la liste des textes
  2. #define STR_STOP 0
  3. #define STR_STOP2 1
  4. #define STR_CHOIXPRINCIPAL 2
  5. #define STR_CONTROLELOCO 3
  6. #define STR_CHOIXCONFIG 4
  7. #define STR_RESETCONFIG 5
  8. #define STR_OUI 6
  9. #define STR_NON 7
  10. #define STR_CONFIRMER 8
  11. #define STR_RETROECLAIRAGE 9
  12. #define STR_INCREMENT 10
  13. #define STR_NOM 11
  14. #define STR_ADRESSELOCO 12
  15. #define STR_SPLASH1 13
  16. #define STR_SPLASH2 14
  17. #define STR_SUPPRIMER 15

Enfin comme on va utiliser les indices de ces chaînes dans la liste un peu partout, je préfère avoir STR_INCREMENT plutôt que 10 dans le reste du programme, il est fortement conseillé de suivre cette pratique, mais ce n’est pas une obligation…

Les fenêtres

  1. // Objets principaux
  2. LiquidCrystal lcd(7, 6, 5, 4, 3, 2);
  3. LcdUi lcdui;
  4. ScreenLiquid ecran;
  5.  
  6. // Variables modifiees par les fenêtres
  7. bool retroEclairage;
  8. Choice choixPrincipal;
  9. Choice choixConfiguration;
  10.  
  11. WindowSplash winSplash;
  12. WindowChoice winChoixPrincipal;
  13. WindowChoice winChoixConfiguration;
  14. WindowInt winAdresse;
  15. WindowInt winIncrement;
  16. WindowText winNom;
  17. WindowYesNo winRetroEclairage;
  18. WindowConfirm winReset;
  19. WindowLocoControl winLoco;
  20. WindowInterrupt winStop;

Au début, il y a quelques déclarations de variables comme l’écran LiquidCrystal qui sera utilisé, LcdUi lui même, l’écran associé ecran, des variables dont les valeurs seront modifiées par le menu, et les différentes fenêtres de ce menu. Je reviendrais sur WindowLocoControl encore plus tard.

Passons au setupUI :

  1. void setupUI()
  2. {
  3. ecran.begin(16, 2, string_table, &lcd);
  4. lcdui.begin(&ecran);
  5.  
  6. LcdScreen::YesMsg = STR_OUI;
  7. LcdScreen::NoMsg = STR_NON;
  8. LcdScreen::BackspaceMsg = STR_SUPPRIMER;

Au début, l’écran est initialisé avec 16 caractères, 2 lignes, la liste des textes de l’interface, et l’écran LiquidCrystal. Après le begin() de lcdUi, on donne l’indice de trois messages essentiels à l’interface : YesMsg, NoMsg et BackspaceMsg, stockés dans des variables globales (statiques pour être précis) à la classe LcdScreen !

  1. winSplash.begin(STR_SPLASH1, STR_SPLASH2, 2000);
  2. winChoixPrincipal.begin(STR_CHOIXPRINCIPAL, &choixPrincipal);
  3. winChoixConfiguration.begin(STR_CHOIXCONFIG, &choixConfiguration);
  4. winAdresse.begin(STR_ADRESSELOCO, &winLoco.Adresse);
  5. winIncrement.begin(STR_INCREMENT, &winLoco.Increment128);
  6. winNom.begin(STR_NOM, winLoco.Nom, 14);
  7. winRetroEclairage.begin(STR_RETROECLAIRAGE, &retroEclairage);
  8. winReset.begin(STR_RESETCONFIG, STR_CONFIRMER);
  9. winLoco.begin(STR_CONTROLELOCO);
  10. winStop.begin(STR_STOP, STR_STOP2, EVENT_STOP);

Les fenêtres sont initialisées une par une par un appel à leur begin(), avec la plupart du temps un identifiant qui est aussi le numéro du message principal de cette fenêtre, souvent suivi par la variable qui sera modifiée lorsque l’utilisateur manipulera cette fenêtre.
Par exemple, c’est la variable choixPrincipal qui sera modifiée lorsqu’une nouvelle sélection sera faite dans la fenêtre winChoixPrincipal.

La première fenêtre de l’interface est l’affichage d’un copyright pendant deux secondes, une WindowSplash avec le texte STR_SPLASH1 sur la première ligne, et STR_SPLASH2 sur la seconde. STR_SPLASH1 est aussi l’identifiant de cette fenêtre. Lorsque le temps est écoulé, LcdUi passe tout seul à la fenêtre suivante [1].

Viennent ensuite les deux menus, le principal

et la configuration,

puis les écrans de saisie de cette config : l’adresse de la loco pilotée en DCC,

l’incrément de vitesse utilisé,

son nom avec quatorze caractères maxi à cause de l’écran,

l’activation, ou pas, du rétro-éclairage de l’écran Lcd,

et la fenêtre de réinitialisation de la configuration.

suit la fenêtre spécifique winLoco dont on finira bien par parler !

La dernière fenêtre winStop est une interruption qui envoie un événement bien particulier : EVENT_STOP

  1. lcdui.AddWindow(&winSplash);
  2. lcdui.AddWindow(&winChoixPrincipal);
  3. lcdui.AddWindow(&winChoixConfiguration);
  4. lcdui.AddWindow(&winAdresse);
  5. lcdui.AddWindow(&winIncrement);
  6. lcdui.AddWindow(&winNom);
  7. lcdui.AddWindow(&winRetroEclairage);
  8. lcdui.AddWindow(&winReset);
  9. lcdui.AddWindow(&winLoco);
  10. lcdui.AddWindow(&winStop);

L’interface utilisateur est constituée de fenêtres qui se succèdent. C’est une liste ordonnée et hiérarchique des écrans présentés à l’utilisateur. Pour construire cette hiérarchie, il faut ajouter de nouvelles fenêtres à la liste générale de lcdui à l’aide de AddWindow(). L’indentation (le décalage à droite…) illustre la hiérarchie des fenêtres d’une manière purement graphique et sans effet sur le code produit. C’est juste plus compréhensible comme cela.

  1. winChoixPrincipal.AddChoice(STR_CHOIXCONFIG, &winChoixConfiguration);
  2. winChoixConfiguration.AddChoice(STR_ADRESSELOCO, &winAdresse);
  3. winChoixConfiguration.AddChoice(STR_INCREMENT, &winIncrement);
  4. winChoixConfiguration.AddChoice(STR_NOM, &winNom);
  5. winChoixConfiguration.AddChoice(STR_RETROECLAIRAGE, &winRetroEclairage);
  6. winChoixConfiguration.AddChoice(STR_RESETCONFIG, &winReset);
  7. winChoixPrincipal.AddChoice(STR_CONTROLELOCO, &winLoco);

Une fois la liste construite il faut fixer les liens entre les différentes fenêtres : winChoixPrincipal est le menu principal, celui qui va permettre de choisir ce que l’on fait. Il est rempli avec deux options : STR_CHOIXCONFIG le choix secondaire pour la configuration qui ouvre la fenêtre winChoixConfiguration, et STR_CONTROLELOCO la fenêtre de pilotage, la fameuse winLoco [2]
Pour winChoixConfiguration aussi, les différentes options/fenêtres de configuration sont reliées.

Puis on va initialiser les variables de travail :

  1. // Valeurs de départ des variables globales
  2. retroEclairage = false;
  3. winChoixPrincipal.SetCurrentChoiceById(STR_CONTROLELOCO);
  4. }

Le choix principal est tout de suite forcé sur l’option STR_CONTROLELOCO, encore winLoco !

Enfin vient loopUI(). Cette fonction reçoit en argument l’événement LcdUi que le croquis Dcc.ino a identifié grâce à Commanders à partir des interactions de l’utilisateur sur les boutons. Je rappelle que de base LcdUi ne connait que six événements :

  • EVENT_NONE : il ne se passe rien !
  • EVENT_MORE : option du menu ou valeur +1
  • EVENT_LESS : option du menu ou valeur -1
  • EVENT_SELECT : un ’Ok’
  • EVENT_CANCEL : un ’échappe’

Un autre événement, local à notre exemple a été créé. Il s’agit de EVENT_STOP utilisé lorsque le bouton d’urgence est pressé. Il est possible de créer autant d’événements que l’on souhaite, avec la seule limite de ne pas réutiliser les valeurs des événements définis par LcdUi elle même… Il suffit pour cela d’utiliser des valeurs supérieures à dix.
Chaque fenêtre interprète ces événements selon son bon vouloir…

  1. void loopUI(byte inEvent)
  2. {
  3. if (inEvent == EVENT_STOP)
  4. {
  5. Serial.println("Arret d'urgence !");
  6. }
  7.  
  8. if (lcdui.loop(inEvent))
  9. {
  10. Window *pCurrent = lcdui.GetGlobalCurrentWindow();
  11.  
  12. // Faire ce qui doit etre fait apres une confirmation
  13. if (lcdui.GetState() == STATE_CONFIRMED)
  14. {
  15. switch (pCurrent->GetWindowId())
  16. {
  17. case STR_ADRESSELOCO:
  18. Serial.print("Nouvelle adresse: ");
  19. Serial.println(winLoco.Adresse);
  20. break;
  21. case STR_INCREMENT:
  22. Serial.print("Nouvel incrément: ");
  23. Serial.println(winLoco.Increment128);
  24. break;
  25. case STR_NOM:
  26. Serial.print("Nouveau nom: ");
  27. Serial.println(winLoco.Nom);
  28. break;
  29. case STR_RETROECLAIRAGE:
  30. Serial.print("Retro-eclairage: ");
  31. Serial.println(retroEclairage);
  32. break;
  33. case STR_RESETCONFIG:
  34. Serial.println("Reset Config.");
  35. retroEclairage = false;
  36. winLoco.Adresse = 3;
  37. winLoco.FormatAdresse = 3;
  38. winLoco.Vitesse = 0;
  39. winLoco.VitesseMax = 128;
  40. winLoco.Increment128 = 10;
  41. winLoco.Direction = true;
  42. strcpy(winLoco.Nom, "Locoduino");
  43. break;
  44. case STR_STOP:
  45. Serial.println("Fin de l'urgence");
  46. break;
  47. }
  48. }
  49. }
  50. }

Le premier test vérifie que l’événement n’est pas une urgence. Si c’est le cas, un message console est envoyé dans cet exemple, mais sur une vraie centrale il faudrait donner l’ordre DCC d’arrêt immédiat puis couper l’alimentation.

L’événement reçu, urgence ou pas, est ensuite transmis à lcdui.loop() qui va le traiter et faire réagir les fenêtres en conséquence. loop() renvoie un booléen qui signale si l’événement a été traité ou non. S’il n’a pas été traité, c’est sans doute qu’il n’a pas de signification pour la fenêtre en cours, donc inutile de s’en préoccuper ici. Par exemple EVENT_MORE et EVENT_LESS ne signifient rien pour une fenêtre d’urgence… S’il a été traité, on récupère l’état courant de la fenêtre courante avec lcdui.GetState(). L’état qui nous intéresse ici est juste STATE_CONFIRMED qui signale que quelque chose a été validé dans la fenêtre en cours. Selon l’identifiant de la fenêtre, son premier message, on va décider quoi faire. Dans notre exemple, les modifications des valeurs de configuration seront confirmées par un texte affiché sur la console. Sur une véritable centrale DCC, il faudrait adapter la configuration de la partie DCC avec les données saisies. Par exemple lui dire que l’adresse de la loco à piloter n’est plus 3 mais 25. Le cas de l’urgence est aussi traité. Si une urgence est en cours et que l’état de la fenêtre est passé à STATE_CONFIRMED, c’est que l’urgence a été levée. Un message console est affiché pour l’exemple, mais la centrale DCC devrait rétablir l’alimentation et envoyer l’ordre de reprendre le cours normal des opérations.

Et si je veux ouvrir ma fenêtre ?

Il est possible de définir complètement une fenêtre selon des besoins particuliers, soit en modifiant légèrement le comportement d’une fenêtre de base, soit en en créant une de toutes pièces.
Dans notre exemple, il nous faut piloter une loco. Nous avons besoin d’une fenêtre donnant le sens de marche et la vitesse de la loco courante. Nous y mettrons aussi l’adresse DCC de la loco, et son nom. Voici WindowLocoControl.hpp :

  1. #define WINDOWTYPE_CONTROLELOCO 100
  2.  
  3. class WindowLocoControl : public Window
  4. {
  5. public:
  6. int Adresse;
  7. byte FormatAdresse; // nombre de caractères pour l'affichage : 3 pour '025'
  8. byte Vitesse; // Entre 0 et vitesseMax
  9. byte VitesseMax; // 14, 28 ou 128
  10. int Increment128; // un entier juste parce que la fenêtre ne sait pas gérer autre chose
  11. bool Direction;
  12. char Nom[20];
  13.  
  14. public:
  15. WindowLocoControl();
  16.  
  17. inline byte GetType() const { return WINDOWTYPE_CONTROLELOCO; }
  18. void Event(byte inEvenement, LcdUi *inpLcd);
  19.  
  20. void printWindow() { Serial.println("WindowLocoControl"); }
  21. };

La classe de la fenêtre WindowLocoControl est dérivée de la classe de base de toutes les fenêtres : LcdUi::Window. Chaque fenêtre dispose d’un type qui permet d’identifier son comportement. C’est le rôle de WINDOWTYPE_CONTROLELOCO, retourné par la fonction GetType().
Nous sommes ici dans de l’objet pur sucre ! Si vous ne l’avez pas déjà fait, je vous conseille de vous plonger dans Le monde des objets (1) pour comprendre la suite… Dans les données membres, on trouve les valeurs de configuration liées à la locomotive pilotée, comme son adresse DCC ou son nom. On y trouve aussi des données qui sont locales comme la vitesse courante Vitesse, ou le sens du mouvement Direction. Le constructeur n’a pas d’argument.
GetType() est une fonction qui surcharge la fonction virtuelle de base de Window. En effet chaque type de fenêtre retournera un type différent. Comme cette fonction ne fait que renvoyer une valeur sans toucher à l’objet propriétaire this, le mot clé const est employé. Enfin la fonction principale, Event(), qui surcharge aussi la virtuelle de Window, va recevoir les événements du programme principal et les traiter comme elle l’entend. Voyons WindowLocoControl.cpp :

  1. /*************************************************************
  2. project: <Dcc Controler>
  3. author: <Thierry PARIS/Locoduino>
  4. description: <Class for a loco control window>
  5. *************************************************************/
  6.  
  7. #include "WindowLocoControl.hpp"
  8.  
  9. WindowLocoControl::WindowLocoControl()
  10. {
  11. this->Adresse = 3;
  12. this->FormatAdresse = 3;
  13. this->Vitesse = 0;
  14. this->VitesseMax = 128;
  15. this->Increment128 = 10;
  16. this->Direction = true;
  17. strcpy(this->Nom, "Locoduino");
  18. }

Au début de WinLocoControl.cpp, après l’include de base, le constructeur ne fait rien d’autre qu’initialiser toutes ses données avec des valeurs basiques. C’est une partie à ne pas négliger. Si vous n’initialisez pas vos données, n’importe quoi peut s’y trouver, et le comportement du programme sera complètement erratique !

Les événements

La ’vie’ d’une fenêtre passe par cinq états :

  • STATE_START : la fenêtre est ouverte, mais l’écran contient le texte de l’ancienne fenêtre. Il faut tracer le contenu de la nouvelle fenêtre.
  • STATE_INITIALIZE : la fenêtre est ouverte, il faut initialiser ses variables si besoin.
  • STATE_NONE : c’est un état d’attente pour les événements de LcdUi comme EVENT_MORE, EVENT_LESS, EVENT_SELECT ou EVENT_CANCEL.
  • STATE_CONFIRMED : la fenêtre a été validée ou
  • STATE_ABORTED : la fenêtre a été annulée !

Event() va réagir à ces états et aux événements extérieurs. Chaque fenêtre connait son état courant, et l’éventuel événement est passé en argument, avec l’interface générale LcdUi concernée. En effet pour gérer plusieurs écrans, il faudrait déclarer autant instances de LcdUi, avec pour chaque sa liste de fenêtres, sa liste de textes, etc… C’est d’ailleurs ce que j’avais mis en place pour la vidéo du premier article. La fonction Event() a besoin de l’écran concerné pour afficher son texte, et elle le retrouve depuis son LcdUi propriétaire inpLcd.

  1. void WindowLocoControl::Event(byte inEvenement, LcdUi *inpLcd)
  2. {
  3. bool afficheValeur = false;
  4. LcdScreen *pEcran = inpLcd->GetScreen();
  5.  
  6. if (this->state == STATE_START)
  7. {
  8. pEcran->clear();
  9. LcdScreen::BuildString(this->Adresse, LcdScreen::buffer, this->FormatAdresse);
  10. pEcran->DisplayText(LcdScreen::buffer, 0, 0);
  11. byte len = LcdScreen::BuildString(this->Nom, pEcran->GetSizeX() - (this->FormatAdresse + 1), LcdScreen::buffer);
  12. pEcran->DisplayText(LcdScreen::buffer, pEcran->GetSizeX() - len, 0);
  13. this->state = STATE_NONE;
  14. afficheValeur = true;
  15. }
  16.  
  17. byte inc = 1;
  18.  
  19. if (this->VitesseMax == 128)
  20. inc = this->Increment128;
  21.  
  22. switch (inEvenement)
  23. {
  24. case EVENT_MORE:
  25. {
  26. unsigned int nouvelleValeur = this->Vitesse + inc;
  27. if (nouvelleValeur > this->VitesseMax)
  28. nouvelleValeur = this->VitesseMax;
  29. this->Vitesse = nouvelleValeur;
  30. }
  31. afficheValeur = true;
  32. break;
  33.  
  34. case EVENT_LESS:
  35. {
  36. int nouvelleValeur = this->Vitesse - inc;
  37. if (nouvelleValeur < 0)
  38. nouvelleValeur = 0;
  39. this->Vitesse = nouvelleValeur;
  40. }
  41. afficheValeur = true;
  42. break;
  43.  
  44. case EVENT_SELECT:
  45. this->Direction = !this->Direction;
  46. afficheValeur = true;
  47. break;
  48. case EVENT_CANCEL:
  49. this->state = STATE_ABORTED;
  50. break;
  51. }
  52.  
  53. if (afficheValeur)
  54. {
  55. // 01234567879012345
  56. // 0 Dcc 003
  57. // 1 +>>>>> -
  58. // 01234567879012345
  59. int vitesse = this->Vitesse;
  60. if (vitesse == 1)
  61. vitesse = 0;
  62. LcdScreen::BuildProgress(vitesse, this->Vitesse, this->Direction, pEcran->GetSizeX(), LcdScreen::buffer);
  63. pEcran->DisplayText(LcdScreen::buffer, 0, 1);
  64. }
  65. }

Un variable booléenne afficheValeur est utilisée pour savoir si la partie variable de l’écran doit être rafraîchie ou pas. Une autre variable locale pEcran est utilisée pour simplifier le codage plutôt que d’appeler inpLcd->GetScreen() à chaque ligne ou presque…

Lorsque la fenêtre est ouverte pour la première fois, le noyau LcdUi l’a placée en état STATE_START. C’est le démarrage. Le première chose à faire est un pEcran->clear() pour nettoyer l’écran du texte de la fenêtre précédente. Une chaîne de caractères est construite d’après l’adresse DCC. La fonction LcdScreen::BuildString() formatte le contenu de la chaîne LcdScreen::buffer avec un nombre entier, ici l’adresse de la loco, cadré à droite sur trois caractères de long, ce qui donne ’025’. La longueur est donnée par la donnée membre this->FormatAdresse . LcdScreen::buffer est un tableau de caractères fourni par la bibliothèque et utilisé partout comme fourre-tout pour éviter de devoir redéfinir des ’buffer’ partout…
pEcran->DisplayText() va placer le texte demandé aux coordonnées voulues. Ici encore c’est LcdScreen::buffer que l’on vient de remplir qui doit être placée en haut à gauche de l’écran. Les coordonnées sont donc 0 pour le numéro de caractère de départ, et 0 pour la première ligne.
L’état STATE_START est achevé, il faut passer la fenêtre à l’état suivant. L’état STATE_INITIALIZE n’est pas utile ici, c’est donc directement à STATE_NONE que l’on passe. Pour être sûr que la barre de vitesse est bien affichée dès le départ, on met afficheValeur à true. Dans le cas STATE_START, l’événement passé en argument est EVENT_NONE, c’est à dire qu’il ne se passe rien… On va donc passer le switch sans rien faire et juste traiter le afficheValeur pour afficher la barre de vitesse avec la fonction LcdScreen::BuildProgress(). Cette fonction construit une chaîne représentant une quantité de ’>’ proportionnelle à la valeur Vitesse passée en argument. En DCC, une vitesse de 0 n’existe pas, c’est pourquoi une vitesse de 1 est convertie pour l’affichage en 0. Pour calculer la proportion, la valeur mini est fixée arbitrairement à 0, le maxi this->VitesseMax est passé en argument. La direction permet de choisir entre des ’>’ et des ’<’ mais aussi d’inverser les ’+’ et ’-’ aux extrémités de la barre. Enfin la taille maxi de la barre et la chaîne de caractères à remplir (LcdScreen::buffer bien sûr) ferment la liste des arguments. Le texte est affiché sur la seconde ligne, numérotée 1 puisque la première est la zéro.

On va dans un sens


Ou dans l’autre !

Au passage suivant dans Event(), on va tester sur son type pour dire quoi faire :

  • EVENT_MORE et EVENT_LESS vont ajouter ou retirer de la vitesse courante l’incrément donné par la donnée membre this->Increment128, lequel ne s’applique que si la vitesse maxi est bien de 128. Dans les autres cas, c’est un incrément de 1 qui est utilisé. Cette modification de la vitesse s’assurera aussi qu’elle reste dans les limites permises de 0 et 128.
  • EVENT_SELECT change la direction
  • EVENT_CANCEL sort de la fenêtre et retourne au menu précédent.

Ce programme de démo est bien sûr livré en français [3] avec la bibliothèque (Exemples/LcdUi//Locoduino/Dcc) pour vous permettre de juger sur pièce et pourra aussi vous servir de point de départ pour une nouvelle interface. Pour vous éviter de piétiner sur un problème de définition, n’oubliez pas d’activer le mode DEBUG en modifiant la ligne #define LCDUI_DEBUG_MODE au début de lcdui.h . La bibliothèque vérifie pour vous la cohérence de votre interface et signale tout problème sur la console. C’est une aide précieuse tant que l’Arduino n’est pas en production. Veillez simplement à l’enlever avant de compiler la version définitive de votre programme. Le mémoire s’en trouvera sensiblement allégée !

[1Les copies d’écran utilisent un écran 20 caractères sur quatre lignes pour plus de visibilité…

[2le suspense continue…

[3L’équivalent Anglais est dans Exemples/LcdUi/Dcc

Réagissez à « Bibliothèque LcdUi (2) »

Qui êtes-vous ?
Votre message

Pour créer des paragraphes, laissez simplement des lignes vides.

Lien hypertexte

(Si votre message se réfère à un article publié sur le Web, ou à une page fournissant plus d’informations, vous pouvez indiquer ci-après le titre de la page et son adresse.)

Rubrique « Bibliothèques »

Bibliothèque Servo

Bibliothèque SoftWare Serial

Bibliothèque Serial

Bibliothèque EEPROM

Bibliothèque Wire : I2C

Bibliothèque LCD

Bibliothèque ScheduleTable

Bibliothèque MemoryUsage

Bibliothèque EEPROMextent

Bibliothèque Commanders

Bibliothèque DcDccNanoController

Bibliothèque Accessories (1)

Bibliothèque Accessories (2)

Un décodeur d’accessoires universel (1)

Un décodeur d’accessoires universel (2)

Un décodeur d’accessoires universel (3)

Les derniers articles

Bibliothèque DcDccNanoController


Thierry

Bibliothèque LcdUi (2)


Thierry

Bibliothèque LcdUi (1)


Thierry

Bibliothèque Accessories (2)


Thierry

Bibliothèque Accessories (1)


Thierry

Bibliothèque Commanders


Thierry

Bibliothèque MemoryUsage


Thierry

Bibliothèque Wire : I2C


Dominique, Guillaume

Bibliothèque Serial


Dominique, Guillaume, Jean-Luc

Bibliothèque SoftWare Serial


Dominique, Guillaume

Les articles les plus lus

Bibliothèque DcDccNanoController

Bibliothèque Serial

Bibliothèque Wire : I2C

Un décodeur d’accessoires universel (1)

Un décodeur d’accessoires universel (3)

Bibliothèque Commanders

Bibliothèque Accessories (1)

Un décodeur d’accessoires universel (2)

Bibliothèque LCD

Bibliothèque LcdUi (1)